スポンサーサイト

-------- | --:--

上記の広告は1ヶ月以上更新のないブログに表示されています。
新しい記事を書く事で広告が消せます。

[ActionScript 3.0] ユーザーがローカルファイルを選択できるようにする

2007-07-07 | 22:55

緑のボタンを押すとファイル選択ダイアログが表示されます。

package {
    import flash.display.*;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.text.*;
    public class FileSelect extends Sprite {
        private var tf:TextField = new TextField();
        private var fileReference:FileReference = new FileReference();
        public function FileSelect( ) {
            addChild(tf);
            tf.autoSize = TextFieldAutoSize.LEFT;
            tf.text="press button";

            // ボタンの作成
            var button:SimpleButton = new SimpleButton( );
            button.x = 20;
            button.y = 40;
            
            button.upState = createCircle( 0x00FF00, 15 );
            button.overState = createCircle( 0xFFFFFF, 16 );
            button.downState = createCircle( 0xCCCCCC, 15 );
            button.hitTestState = button.upState;
            
            // マウスクリックイベントのリスナ登録
            button.addEventListener( MouseEvent.CLICK, handleClick );
            addChild( button );

        }
        private function createCircle( color:uint, radius:Number ):Shape {
            var circle:Shape = new Shape( );
            circle.graphics.lineStyle( 1, 0x000000 );
            circle.graphics.beginFill( color );
            circle.graphics.drawCircle( 0, 0, radius );
            circle.graphics.endFill( );
            return circle;
        }
        private function handleClick( event:MouseEvent ):void {
            // ファイル選択イベントのリスナ登録
            fileReference.addEventListener(Event.SELECT, onSelectFile);
            fileReference.browse();
        }
        private function onSelectFile( event:Event ):void {
            // 選択されたファイル名の表示
            tf.text = fileReference.name;
        }
    }
}

スポンサーサイト
上記広告は1ヶ月以上更新のないブログに表示されています。新しい記事を書くことで広告を消せます。